Moin,
nun melde ich mich mal zurück. Ich hatte in den letzten Monaten viel zu tun. So blieben manche Dinge einfach auf der Strecke.
Heute möchte ich mir ein kleine Erinnerung hinterlegen: Wie binde ich eine Truecrpt Datei per Batch ein. In meinem Verfolgungswahn habe ich mir angewöhnt, Datenträger mit privaten Daten generell zu verschlüsseln. Da in beruflich mit Windoof arbeite, aber zu Hause ausschließlich Ubuntu nutze, ist Truecrypt eine geeignete Lösung für beide Welten.
Auf einer 2GB SD-Karte habe ich einen 2GB großen Truecrypt Container erzeugt. Wie das geht, könnt ihr euch leicht im Internet anlesen. All morgendlich schiebe ich nun meine SD-Karte in mein Firmen Notebook und benutze mit Mouse und Tastatur die Truecrypt Oberfläche, um diesen Container zu öffnen. Faul wie ich bin, habe ich mir nun eine kleine Batch-Datei zusammen getippt, die nur noch das Passwort erfragt. Nein, ich habe die Batch-Datei nicht erfunden, sondern habe mit google und der Online-Hilfe von Truecrypt das Nötigste zusammen-raub-kopiert und mache mir somit das Wissen Anderer zueigen.
Kleine Warnung vorweg: Ich habe darauf verzichtet eine verdeckte Passworteingabe zu ermöglichen. Das Passwort wird im Klartext erfragt. Du solltest also entsprechend vorsichtig sein, damit es niemand sieht.
Die folgenden Zeilen einfach in eine Textdatei kopieren und als <name>.bat abspeichern.
CLS
@ECHO off
REM
REM Truecrypt Datei per Batch öffnen und mounten
REM
SET driveletter=z
SET TCpathfile=<pfad>\TruecryptDateiname
SET TCexePath=<pfad>\TrueCrypt.exe
:check_file
REM ****************************************************
REM ** pruefe, ob %TCpathfile% vorhanden ist
REM ****************************************************
ECHO Check: Truecrypt Datei (%TCpathfile%) vorhanden.
IF EXIST %TCpathfile% GOTO check_letter
GOTO abbruch_f
:check_letter
REM ****************************************************
REM ** pruefe, ob %driveletter% bereits verbunden
REM ****************************************************
ECHO OK
ECHO Check: Laufwerk %driveletter%:\ frei.
IF NOT EXIST %driveletter%:\NUL GOTO pw_input
GOTO abbruch_l
:pw_input
REM ****************************************************
REM ** Passwort eingeben (im Klartext)
REM ****************************************************
ECHO OK
SET /p password="Passphrase: "
CLS
GOTO connect_z
:connect_z
ECHO Truecrypt Datei (%TCpathfile%) oeffnen und als %driveletter%:\ mounten.
%TCexePath% /v %TCpathfile% /l%driveletter% /p "%password%" /q
ECHO OK
GOTO end
REM ****************************************************
REM ** Abbruch
REM ****************************************************
:abbruch_f
ECHO Abbruch!! Truecrypt Datei (%TCpathfile%) nicht gefunden
GOTO end
:abbruch_l
ECHO Abbruch!! Laufwerk %driveletter%:\ bereits vergeben.
GOTO end
:end
REM ****************************************************
REM ** ENDE
REM ****************************************************
Pause
Nach dem Abspeichern einfach mit Doppelklick ausführen.
Viel Spass ihr Nasen.
Mikkel
